マルチタイムフレームRSI for MT5

本記事のテーマ

本記事ではMQL5で書かれたマルチタイムフレームRSIのコードの解説をしていきます。
仕組みを理解することで、RSIだけでなく、ほかのインジケータのマルチタイムフレーム対応版を作れるようになります。

ソースコード

#property copyright   "© shanch, 2020"
#property link        "shanch2@gmail.com"
#property description "MTFRSI"

#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1

#property indicator_type1   DRAW_LINE
#property indicator_color1  clrDodgerBlue
#property indicator_width1  1
#property indicator_style1  STYLE_SOLID

input ENUM_TIMEFRAMES  TimeFrame = PERIOD_H1;
input int Period = 14;
input ENUM_APPLIED_PRICE  AppliedPrice = PRICE_CLOSE;

int hRsi;
double BufRsi[];
double BufTemp[];

int OnInit()
{
   SetIndexBuffer(0, BufRsi, INDICATOR_DATA);
   ArraySetAsSeries(BufRsi, true);
   
   ArraySetAsSeries(BufTemp, true);
   
   IndicatorSetInteger(INDICATOR_LEVELS,3);
   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,30);
   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,50);
   IndicatorSetDouble(INDICATOR_LEVELVALUE,2,70);
   IndicatorSetDouble(INDICATOR_MINIMUM,0);
   IndicatorSetDouble(INDICATOR_MAXIMUM,100);
     
   hRsi = iRSI(NULL, TimeFrame, Period, AppliedPrice);

   return(INIT_SUCCEEDED);
}

void OnDeinit(const int reason)
{
    IndicatorRelease(hRsi);
}

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,true);
   
   int limit = rates_total - prev_calculated;
   if(limit == 0) limit= 1;
   
   int shift = 0;

   for(int i=0; i<limit; i++)
   {
      shift=iBarShift(_Symbol,TimeFrame,time[i]);
      
      if(CopyBuffer(hRsi, 0, shift, 1, BufTemp) <= 0)
      {
         Print("Getting RSI failed! Error",GetLastError());
         return(0);
      }
      else
      {
          BufRsi[i]=BufTemp[0];
      }
   }

   for(int i=1; i<rates_total; i++)
   {
      if(iBarShift(NULL, TimeFrame, time[i]) > 0)
      {
         break;
      }
      BufRsi[i]=BufRsi[0];
   }

   return(rates_total);
}